Вопрос: У пакетных файлов Windows есть конструкция% *?


В пакетном файле мне нужно сделать (например) следующее:

@echo off
call other.bat %1 %2 %3 %4 %5 %6 %7 %8 %9

6
2018-06-09 09:35


Источник


Подобно $ @ на Unix - An̲̳̳drew


Ответы:


Пакетные файлы Windows (начиная с Windows XP, но, возможно, раньше) поддерживают %* construct, который оценивает все параметры из% 1 и далее.

К сожалению, это не SHIFT , поэтому следующее не будет работать:

@echo off
set EATEN=%1
shift

call other.bat %*

Он все равно передаст первый параметр во второй командный файл.


7
2018-06-09 09:37





Вы можете собрать все аргументы вместе, используя что-то вроде:

set args=%1
shift
:start
if [%1] == [] goto done
set args=%args% %1
shift
goto start

:done
(use %args% here)

Это работает независимо от количества аргументов.


3
2018-06-09 12:56





Если вы хотите, например, пропустить первые 3 параметра и передать остальные:

@echo off
for /f "tokens=1-3*" %%a in ("%*") do (
   set par1=%%a
   set par2=%%b
   set par3=%%c
   set therest=%%d
   )

call other.bat %therest%

Там могут быть проблемы с кавычками в параметрах.

престиж Патрику Каффу, https://stackoverflow.com/questions/382587/how-to-get-batch-file-parameters-from-nth-position-on


2
2018-06-09 09:43





Да, да.

Вы можете написать свой пример следующим образом:

@echo off
call other.bat %*

Также: сдвиг поддерживается в окнах ... См. это,
Но действительно, эта последняя ссылка подтверждает, что сдвиг не работает в сочетании с% *:

• Использование% * с сдвиг
  сдвиг не влияет на параметр партии% *.


1
2018-05-18 07:49



Извините, ссылки были плохими ... должны быть исправлены. - fretje
(цитата) Использование% * со сдвигом Shift не влияет на параметр партии% *. (/ quote) - Wedge
Почему нисходящий? Вопрос был о% * не о сдвиге. - fretje
В вашем первом ответе было только «Да, они делают», что не было очевидной ссылкой (или ответом). Последнее редактирование - это гораздо более достойный ответ, возможно, поэтому ... - thijs
Фактически, downvote произошло после того, как я добавил больше объяснений. И я согласен, что ссылка на «Да, они делают» не была очевидна, но это был точный ответ на вопрос ... - fretje


@echo off
cls
setlocal enabledelayedexpansion

:: Disable the display of information by changing [set "_ENABLE_INFO="] to [set "_ENABLE_INFO=::"].
set "_ENABLE_INFO="
set _DBQ="

set "_PARMS.ORIGINAL=%*" && if defined _PARMS.ORIGINAL (
   if not defined _PARMS.IDX (
      echo Parameter Index^(es^) to extract eg.:
      echo 1 2 5 9 11 39 400
      set /p "_PARMS.IDX=>"
   )
   set "_PARMS.IDX=¡!_PARMS.IDX: =¡ ¡!¡"
   set "_PARMS.IDX=!_PARMS.IDX:¡¡=!"
   set "_PARMS.IDX=!_PARMS.IDX: =!"
   call :_FN_PROC.STRING %*
%_ENABLE_INFO% goto :FINISH
   goto :eof
) else (
   echo No input parameters.
)
goto :eof


:_FN_PROC.STRING
set "_PARMS.PROCESS.STRING=%*"
:_FN_PROC.STRING.LOOP
set "_PARMS.PROCESS.STRING=!_PARMS.PROCESS.STRING:%_DBQ%=¡!"
set /a _PARMS.COUNT+=1
for /f "tokens=1* delims= " %%a in ("!_PARMS.PROCESS.STRING!") do (
   set _PARMS.TMP.CHECK=%%a
   set _PARMS.PROCESS.STRING=%%b
   if "!_PARMS.TMP.CHECK!" NEQ "!_PARMS.TMP.CHECK:¡=!" (
      for /f "tokens=1* delims=¡" %%c in ("%%a !_PARMS.PROCESS.STRING!") do (
         set _PARMS.TMP.CHECK="%%c"
         set _PARMS.PROCESS.STRING=%%d
      )
   )
)

if "!_PARMS.IDX:¡%_PARMS.COUNT%¡=!" EQU "!_PARMS.IDX!" (
   set _PARMS.REMAINING=!_PARMS.REMAINING! !_PARMS.TMP.CHECK!
   set _PARMS.IDX=!_PARMS.IDX!{%_PARMS.COUNT%}
) else (
   set _PARMS.EXTRACTED=!_PARMS.EXTRACTED! !_PARMS.TMP.CHECK!
   set _PARMS.IDX=!_PARMS.IDX:¡%_PARMS.COUNT%¡=!
   set _PARMS.IDX=!_PARMS.IDX![%_PARMS.COUNT%]
)

if "!_PARMS.PROCESS.STRING: =!"=="" (set _PARMS.PROCESS.STRING=)
if defined _PARMS.PROCESS.STRING (goto :_FN_PROC.STRING.LOOP)

set _DBQ=
set _PARMS.TMP.CHECK=
if defined _PARMS.REMAINING (set _PARMS.REMAINING=!_PARMS.REMAINING:~1!)
if defined _PARMS.EXTRACTED (set _PARMS.EXTRACTED=!_PARMS.EXTRACTED:~1!)
goto :eof


:FINISH
echo.
echo _PARMS.IDX ^:
echo    ¡^=¡ no Parameter Index was specified for extraction.
echo    ¡n¡ nth Parameter was not processed (Index larger than Parameters Count).
echo    [n] nth Parameter was Extracted.
echo    {n} nth Parameter was Ignored (Remaining).
echo.
set _
goto :eof

0



Сохраняет все специальные разделители. Поддерживает столько параметров, сколько может быть установлено в 8175 символах на лимит командной строки (включая имя файла партии, CRLF и пакетный путь, если это указано). Параметры могут быть сгруппированы с двойными кавычками (например, «sw1 = / quiet / skip: 1 / start = 3»). Примечание. Двойные кавычки сохраняются. Ожидается поведение двойных кавычек (даже если оно используется неправильно, например, используется только однократно или «или»). Прежде чем сделать отчет об ошибке, сначала отлаживайте код. - Dharma Leonardi